VB

Macro Guidelines for Excel VBA Beginners

Ryan Van Slooten — Tue, 27 May 2008 23:28:20 GMT

I'm in the process of updating an Excel spreadsheet that is failing when it is running inside of Internet Explorer. The issue is related to the ActiveSheet and other global properties having a value of Nothing when the code is assuming they have valid references. As I am going through this spreadsheet, I am noting a wide variety of programming deficiencies and inefficiencies. Here is a list of some of the issues encountered:

If you run spreadsheets under Internet Explorer, use Application.ThisWorkbook and to ensure the browser evaluates the reference correctly.

NOTE: This is not an exhaustive list, nor do I claim that the "Better" examples are the best code example, but rather they are (hopefully) significant improvements over the "Bad" examples. In many cases, I have kept the design of the bad example so that you can see the differences however you should strive to completely refactor the code if possible.

Do not abuse the "With" statement in VBA.
Some people like "With" and some people don't and I don't particularly care for it. In particular, do not use nested "With" statements.
Example of Bad Code
```
' ... BAD EXAMPLE: DO NOT USE ...
With ActiveSheet
  With TestForm
    ' ...
  End With ' TestForm
End With ' ActiveSheet
' ... BAD EXAMPLE: DO NOT USE ...
```

Avoid using the "Goto" statement in VBA.

"Goto" is almost always a bad idea and a sign of spaghetti code. There are very few cases were it is appropriate to use it -- very few cases!

Example of Bad Code

' ... BAD EXAMPLE: DO NOT USE ...
For i = iHere To lRealLastRow Step 2
  BuildStr = "A" & i + 1
  Range(BuildStr).Select
  If Range(BuildStr).Value = "---" Then GoTo DoneWithNames
  SelectItemDlg.Items_List.AddItem Range(BuildStr).Text
Next

DoneWithNames:
' ... BAD EXAMPLE: DO NOT USE ...

Example of Better Code (I still would have designed it differently)

' ...
Dim MyCell As Range
For i = iHere To lRealLastRow Step 2
  Set MyCell = Cells(i + 1, 1)
  If MyCell.Value = "---" Then
    Exit For
  End If
  SelectItemDlg.Items_List.AddItem MyCell.Text
Next
' ...

Avoid using the name of a Form inside the Form code

The current form is implied in the code. It is not necessary to use the form name to reference controls on the form. If you want to differeniate form controls, you can use the 'Me' keyword such as: Me.Hide

Example of Bad Code

' ... BAD EXAMPLE: DO NOT USE ...
' This example is doubly bad because it uses the form name (ChartConfig)
' both explicitly and in a With statement
If ChartConfig.Variable1.Text = ChartConfig.Variable2.Text Then
    MsgBox "Variable1 cannot be same as Variable2. Please choose another variable type.", vbOKCancel

    'Turn off the Change effect on Variable2.
    changeCasevar = False
    With ChartConfig
        .Variable2.Text = ""
        .Variable2Desc.Text = ""
        .Variable2Uom.Text = ""
    End With
    'Turn back on the Change effect on Variable2.
    changeCasevar = True
    Exit Sub
    '
End If

' ... BAD EXAMPLE: DO NOT USE ...

Example of Better Code (I still would have designed it differently)

' ...
If Variable1.Text = Variable2.Text Then
    MsgBox "Variable1 cannot be same as Variable2. Please choose another variable type.", vbOKCancel

    'Turn off the Change effect on Variable2.
    changeCasevar = False

    Variable2.Text = ""
    Variable2Desc.Text = ""
    Variable2Uom.Text = ""

    'Turn back on the Change effect on Variable2.
    changeCasevar = True
    Exit Sub
End If

Use Error Handling and Resume to restore Application.ScreenUpdating

Example of Bad Code

' ... BAD EXAMPLE: DO NOT USE ...
' There are quite a few global variables and a pass-by-reference
' boolean that should just be the function return value.
Application.ScreenUpdating = False

iOption = "Single"
x = ChartPicker.Input_Val_Text
Call CheckUserRangeInputsAndOutputs(iOption, OkToChart)
iOption = ""

If OkToChart = True Then
    With ChartConfig
        CreateChartingArrays
    End With
End If

Application.ScreenUpdating = True
' ... BAD EXAMPLE: DO NOT USE ...

Example of Better Code (I still would have designed it differently)

' ...
  On Error GoTo ErrorHandler

  Application.ScreenUpdating = False

  If CheckUserRangeInputsAndOutputs("Single") Then
    ChartConfig.CreateChartingArrays
  End If

Exit_Handler:
  Application.ScreenUpdating = True
  Exit Sub

ErrorHandler:
  MsgBox "Error " & Err.Number & ": " & Err.Description
  Resume Exit_Handler

Use If, Else If, and Else correctly.

Example of Bad Code

' ... BAD EXAMPLE: DO NOT USE ...
If TextBoxMinimum.Text = "" Then
  MsgBox "Must enter Minimum Value before proceeding", vbOK
  Result = False
  Exit Function
End If

If TextBoxMaximum.Text = "" Then
  MsgBox "Must enter Maximum Value before proceeding", vbOK
  Result = False
  Exit Function
End If
' ... BAD EXAMPLE: DO NOT USE ...

Example of Better Code

' ...
' For a explicit method, you can directly refer to the controls
Result = False
If Not IsNumeric(TextBoxMinimum.Text) Then
  MsgBox "Must enter Minimum Value before proceeding", vbOK
  TextBoxMinimum.SetFocus
ElseIf Not IsNumeric(TextBoxMaximum.Text) Then
  MsgBox "Must enter Maximum Value before proceeding", vbOK
  TextBoxMaximum.SetFocus
Else
  Result = True
End If

' If you can use a generic method, you can iterate through all of the controls
' There are obviously better ways of doing this, especially with .NET
Dim ValidateControl
Dim ControlList = Array(TextBox1, TextBox2, TextBox3)
For Each ValidateControl In ControlList
  If Input_Val_Text = Null Or Input_Val_Text = "" Then
    MsgBox "Must enter Value in " & ValidateControl.Name & " before proceeding", vbOK
    Result = False
    Exit Function
  End If
Next

Avoid using the ActiveSheet, Range, Cells, and other global variables.

Rather than assuming a position, it is much better to set a variable to the desired Workbook, Worksheet, or Range.

In particular, if there is any chance the spreadsheet might run under a browser, use Application.ThisWorkbook to ensure the browser evaluates the macro correctly.

Example of Bad Code

' ... BAD EXAMPLE: DO NOT USE ...
'NOTE: Arrays start with 1st position as "0", not "1"
'Thus ColLtrs(0) is not used but placed there as a spacer for letter to column alignment:
ColLtrs = Array("", "A", "B", "C", "D", "E", "F", "G", "H", "I", "J", "K", "L", "M", "N", "O", "P", "Q", "R", "S", "T", "U", "V", "W", "X", "Y", "Z")

With ActiveSheet
  Range(ColLtrs(iOutCol) & iOutRow).Select
    
  If UnitSystem = "Metric" Then
    iRow = ActiveCell.Row
    For i = iRow To iLastRow - 1
      currCell = ColLtrs(ActiveCell.Column) & i + 1

      If Range(currCell).Value <> "" Then
        'capture the value from original calculatated data
        Range(currCell).Select

        strOrigValueCell = ColLtrs(iResultsCol) & ActiveCell.Row
        Result = ConvertUom(Range(strOrigValueCell))
      End If
    Next i
  End If
End With
' ... BAD EXAMPLE: DO NOT USE ...

Example of Better Code

' ...
Dim mySheet As Worksheet
Dim Value As Variant

Set mySheet = ActiveSheet

For i = iRow To iLastRow - 1
  Value = mySheet.Cells(i, iOutCol).Value
  If Value <> "" Then
    Result = ConvertUom(UnitSystem, Value)
  End If
Next i

' To get a column letter/code, do not reinvent the wheel!
' Various functions from:
' http://www.dicks-blog.com/archives/2004/05/21/column-numbers-to-letters/

Function ColLetter(ColNumber As Long) As String
    On Error Resume Next
    ColLetter = Application.Substitute(Application.ConvertFormula("R1C" & ColNumber, xlR1C1, xlA1, 4), "1", "")
End Function

Function ColumnLetter(ByVal c As Long) As String
  Dim p As Long
  While c
    p = 1 + (c - 1) Mod 26
    c = (c - p) \ 26
    ColumnLetter = Chr$(64 + p) & ColumnLetter
  Wend
End Function

Avoid using .Select and moving selection in macros unless absolutely.

Do not change the current sheet or selection unless that is the intention of the macro. In general, don't mess with the user, flip sheets, or other heinous acts and try to leave things the way you found them.

Example of Bad Code

' ... BAD EXAMPLE: DO NOT USE ...
For i = 1 To 10
  Range("A" & i).Select
  ActiveCell.Value = "Row " & i
Next i
' ... BAD EXAMPLE: DO NOT USE ...

Example of Better Code

Dim iColumn As Long
Dim mySheet As Worksheet
Dim myRange As Range

iColumn = 1
Set mySheet = ActiveSheet

For iRow = 1 To 10
  Set rng = mySheet.Cells(iRow, iColumn)
  rng.Value = "Row " & iRow
Next iRow

Throw Away Knowledge

Ryan Van Slooten — Tue, 13 Nov 2007 21:59:16 GMT

I have spent the past hour trying to modify a VBScript / JavaScript utility to print out my password expiration date and it is driving me a little crazy. I cannot understand why something that should be so simple can be so blasted difficult. I have several account at client sites and the password expires periodically. In order to make sure I don't let the account lapse, I wanted to print the password expiration date. I had a version that worked before but the distinguishedName had to be exact. I used the adfind utility to figure out my distinguished name and put it in the script. Today I wanted to remove that limitation but it is proving to be a big waste of time. Every attempt to make this work with either VBScript or JavaScript has been thwarted with malice.

Of couse that doesn't stop me from trying -- oh no! Merely a flesh wound. As a programmer determined to make things work, it will bug me until it actually does work! There is silliness involved such as this code to convert an Integer64 to a useable native data type in VBScript:

numDays = CCur((maxPwdAge.HighPart * 2 ^ 32) + _
                maxPwdAge.LowPart) / CCur(-864000000000)

whenPasswordExpires = DateAdd("d", numDays, oUser.PasswordLastChanged)

JavaScript doesn't have the CCur function so I have to use an alternative (and talk about silly -- using a currency data type to do this!). With both VBScript and JavaScript, I am having trouble searching Active Directory with a query or filter. At this point, I may use C# script where I have full .NET power.

This brings me to the point of this entry. Much of the programming technologies in use are destined for a short lifetime. It is an utter waste to invest time, money, and effort to build complex solutions against technologies and frameworks that will be replaced in two years. It is the dilemma that we find ourselves in though, and sometimes there is no or little choice.

As I write this entry I am looking at the waste land of books including my original C programming textbook from university, a ancient graphics programming book that describes "Mode X", some COM and ATL books, and tucked away somewhere I have the Petzold Win95 book and Prosise MFC Win95 book. Then I start thinking about l-values and r-values, some of the ridiculous MFC hacks I've had to make in the past and I'm glad I don't have to deal with that much anymore. Things have improved especially in the area of dynamic or scripting languages where the power of these languages allow the programmer to accomplish a significant amount of work with less effort. One of the benefits is that is almost forces other languages to add features and streamline for greater efficiency. Unfortunately it is a slow process but I do see progress.

New Printers Breaking (Formerly) Stable Code!

Ryan Van Slooten — Tue, 07 Aug 2007 15:14:40 GMT

I am almost embarassed to mention it, but in a past life I developed several major corporate applications using VB6. The applications are remarkably stable and have only been recompiled three or four times since their original deployment for various fixes or changes. This particular application has been in use for 10 years (since 1997) and uses Crystal Reports 5.0 for printing. Back in the day, I read Visual Basic Programmer's Journal (VBPJ) quite a bit and saw an article about using the Win32 API for Crystal Reports in VB. Since I was more of a C\C++ programmer thrust into the VB programmer role, I instantly liked this article and used these methods in my application. At the time I was not familiar with Hardcode Visual Basic (or here) by Bruce McKinney so this code used a common hack when copying memory into VB:

' Slightly modified code. Original code from VBPJ.
' ... Removed extra code for sample ...

Private Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" _
    (Destination As Any, Source As Any, ByVal Length As Long)

Private Type DevModeBuffer ' Holds DevMode Data.
    sData As String * 4096
End Type

Private m_HoldDevMode   As DevMode
Private m_DModeBuffer   As DevModeBuffer
Private m_lDModeSize    As Long

Public Function SetupPrinter(lFlags As Long) As Boolean
    ' ... Printer setup ...

    ' Get size of DevMode & DevNames from PrintDlg return
    m_lDModeSize = GlobalSize(PDlg.hDevMode)

    ' Fill Buffers with Space to Perpare for copy to.
    m_DModeBuffer.sData = String$(4095, 32)

    ' Lock memory & copy the standard size DevMode.
    lDModePointer = GlobalLock(PDlg.hDevMode)  ' Locks the memory
    Call CopyMemory(m_HoldDevMode, ByVal lDModePointer, Len(m_HoldDevMode))

    ' Copy entire DevMode Structure for later use.
    Call CopyMemory(m_DModeBuffer, ByVal lDModePointer, m_lDModeSize) ' Copies the memory

    ' ... More printer setup ...
End Function

The key to this code is the String * 4096 and the String$(4095, 32) which initializes the buffer. Prior to Hardcode VB, it wasn't really possible to have arbitrary sized buffers because VB passed the String parameter (BSTR) differently to API functions. So people used a fixed buffer size (in this case 4096) in a Type (structure) and VB passed the parameter as a pointer-to-memory, not a pointer-to-a-pointer-to-memory.

After a little bit of debugging, it quickly becomes apparent that this new printer returns a much larger memory block (6952 bytes) and the CopyMemory statement happily copies the entire block regardless of the allocated size. Fortunately, the change was fairly simple.

With the advent of Hardcore VB and the Win.TLB, it was possible to reference DLL functions in a manner that wasn't previously possible by altering the data type and ByVal/ByRef settings. The Win.TLB has a function CopyMemoryLpToStr() so the code essentially becomes:

' Remove the * 4096 from DevModeBuffer.sData

Public Function SetupPrinter(lFlags As Long) As Boolean
    ' ...
    ' Fill Buffers with Space to Perpare for copy to.
    m_DModeBuffer.sData = String$(m_lDModeSize + 1, 32)

    ' Copy entire DevMode Structure for later use.
    Call CopyMemoryLpToStr(m_DModeBuffer.sData, ByVal lDModePointer, m_lDModeSize) ' Copies the memory
    ' ...
End Function

Well I hope this is the last time I have to touch this application. It has been remarkably stable even though I have moved on to different departments several times and no one is actively maintaining it.

Technorati tags: VB6

Formatting XML in Excel/VB

Ryan Van Slooten — Wed, 23 May 2007 15:23:57 GMT

I was working on a spreadsheet that submitted XML data to a web service and the XML that was being generated by the XmlDocument object was not very tidy. Normally with C# I use Tidy.NET to clean up the HTML or XML, but since this was being used in Excel I didn't want to have any external dependencies. I found the following code online and it seems to work pretty well:

Option Explicit

' http://www.vb-helper.com/howto_formatted_xml_document.html
' Add formatting to the document.
Public Sub FormatXmlDocument(ByVal xml_doc As DOMDocument)
    FormatXmlNode xml_doc.documentElement, 0
End Sub

' Add formatting to this element. Indent it and add a
' carriage return before its children. Then recursively
' format the children with increased indentation.
Private Sub FormatXmlNode(ByVal node As IXMLDOMNode, _
                          ByVal indent As Integer)
Dim child As IXMLDOMNode
Dim text_only As Boolean

    ' Do nothing if this is a text node.
    If TypeOf node Is IXMLDOMText Then Exit Sub

    ' See if this node contains only text.
    text_only = True
    If node.hasChildNodes Then
        For Each child In node.childNodes
            If Not (TypeOf child Is IXMLDOMText) Then
                text_only = False
                Exit For
            End If
        Next child
    End If

    ' Process child nodes.
    If node.hasChildNodes Then
        ' Add a carriage return before the children.
        If Not text_only Then
            node.insertBefore _
                node.ownerDocument.createTextNode(vbCrLf), _
                node.FirstChild
        End If

        ' Format the children.
        For Each child In node.childNodes
            FormatXmlNode child, indent + 2
        Next child
    End If

    ' Format this element.
    If indent > 0 Then
        ' Indent before this element.
        node.parentNode.insertBefore _
            node.ownerDocument.createTextNode(Space$(indent)), _
            node

        ' Indent after the last child node.
        If Not text_only Then _
            node.appendChild _
                node.ownerDocument.createTextNode(Space$(indent))

        ' Add a carriage return after this node.
        If node.nextSibling Is Nothing Then
            node.parentNode.appendChild _
                node.ownerDocument.createTextNode(vbCrLf)
        Else
            node.parentNode.insertBefore _
                node.ownerDocument.createTextNode(vbCrLf), _
                node.nextSibling
        End If
    End If
End Sub

Visual Floating Point Debugger Tool

Ryan Van Slooten — Wed, 07 Feb 2007 19:10:43 GMT

When I was debugging communication protocols a long time ago, I would often have to convert a 32-bit integer into a 32-bit floating point number. This did not mean using atof, fscanf, _fcvt or similar function, but rather interpretting the bits as an IEEE 754 or IEC 60559:1989 floating point number. An example would be:

1.0 == 0x3F800000 (1065353216)

In the process, I wrote a tool that displays the components of the floating point number and allows you to change the raw hexadecimal bits. Here is a screen shot:

This tool was written with VB6 however I have always wanted to make a C++/WTL version of the tool. Maybe I will get around to it sometime. Here is a decent article describing the floating point format.

Float Tool Source: 18KB

Export Excel Worksheet to ADO Recordset

Ryan Van Slooten — Mon, 15 Jan 2007 18:22:28 GMT

This weekend I was working on a spreadsheet and I needed to save the data as a recordset. Unfortunately there didn't seem to be a way to do it easily without VBA macros. So I wrote this macro to save the current worksheet as an ADODB.Recordset XML file. Remember to add a reference to Microsoft.ActiveX Data Object 2.8 Library in the Excel Visual Basic Editor.

Public Sub CreateAdoRecordsetXml()
    Dim rst As New ADODB.Recordset
    Dim sheet As Worksheet
    Dim col As Long, colcount As Long
    Dim row As Long, rowcount As Long
    Dim Filename As String

Filename = ActiveWorkbook.Path + "\" + ActiveSheet.Name + ".xml"
    Set sheet = ActiveSheet
    colcount = sheet.UsedRange.Columns.count
    rowcount = sheet.UsedRange.Rows.count

col = 1
    row = 1
    Do While col <= colcount
        Call rst.Fields.Append(sheet.Cells(row, col).Text, adVarChar, 255, adFldMayBeNull)
        col = col + 1
    Loop
    rst.Open

row = 2
    Do While row <= rowcount
        col = 1
        Call rst.AddNew
        With rst.Fields
            Do While col <= colcount
                If sheet.Cells(row, col).Text <> "" Then
                    .Item(col - 1).Value = sheet.Cells(row, col).Text
                End If
                col = col + 1
            Loop
        End With
        Call rst.Update
        row = row + 1
    Loop

Call rst.Save(Filename, adPersistXML)
End Sub

VB

Macro Guidelines for Excel VBA Beginners

Do not abuse the "With" statement in VBA.

Example of Bad Code

Avoid using the "Goto" statement in VBA.

Example of Bad Code

Example of Better Code (I still would have designed it differently)

Avoid using the name of a Form inside the Form code

Example of Bad Code

Example of Better Code (I still would have designed it differently)

Use Error Handling and Resume to restore Application.ScreenUpdating

Example of Bad Code

Example of Better Code (I still would have designed it differently)

Use If, Else If, and Else correctly.

Example of Bad Code

Example of Better Code

Avoid using the ActiveSheet, Range, Cells, and other global variables.

Example of Bad Code

Example of Better Code

Avoid using .Select and moving selection in macros unless absolutely.

Example of Bad Code

Example of Better Code

Throw Away Knowledge

New Printers Breaking (Formerly) Stable Code!

Formatting XML in Excel/VB

Visual Floating Point Debugger Tool

Export Excel Worksheet to ADO Recordset